AHK_ToggleWindow 1.2 >> Programmfenster ohne Titelleiste und Rahmen anzeigen

@thehop · **Registriert:** 15.07.05, 1:33 **Wohnort:** europa.at

Hallo freebies,

Suche eine Art "Borderless & Toolbarless Windowmanager" um Anwendungsfenster von Programmen
(per Hotkey oder Mausklick) im Full Screen Modus anzeigen zu lassen (also ähnlich IE bzw. Opera mit der F11 Taste).

Die Menüs der Toolbar, Taskleisten sollten dabei als Einblendmenüs erhalten bleiben
(z.B. bei Mausberührung der Bildschirmränder oder/und Kontextmenü, Systrayoption etc.)

Icfu hat geschrieben:

AHK_ToggleWindow

2007/12/14 Version 1.2
+ Shortcut Shift+F11: gleiche Funktionalität ohne Maximierung

2007/07/27 Version 1.1
+ Auch die Menüleiste wird entfernt.
+ Der Menü- und Maximierungsstatus aller Fenster wird in einer temporären Datei
(Scriptname.ahk.tmp im Arbeitsverzeichnis) gesichert und wiederhergestellt.
* Shortcut Strg+F11: keine Kollision mit programmeigener Vollansicht-Funktion

Kompilierte Exe+Source:
http://icfu.totalcmd.net/Scripts/AHK_ToggleWindow.zip

EDIT: Anfrage Überschrift in Tooltipp umgewandelt - Danke Icfu :drink:

oliver · **Registriert:** 28.08.06, 15:23

Könnte vielleicht mit Blackbox für Windows funktionieren,

http://www.bb4win.org/news.php

@thehop · **Registriert:** 15.07.05, 1:33 **Wohnort:** europa.at

Laut Beschreibung wäre das eine andere Shell - ich suche eher eine Explorererweiterung
bzw. ein eigenständiges Tool das mit/unter dem Explorer lauffähig ist.

Zitat:

http://www.pcwelt.de/index.cfm?pid=1755&pk=32986&p=6

Blackbox ist ähnlich wie Litestep ein Shell-Ersatz, dessen Grundidee aus der Unix-Welt stammt. Der Stil basiert auf dem unter Linux bekannten Blackbox-Window-Manager. Blackbox ist eine Minimal-Shell für geringste Ansprüche.

oliver · **Registriert:** 28.08.06, 15:23

Nun ja die Shell ist eher etwas anderes und ein WM eben ein WM. Klar es ist ein Ersatz, mitunter ein probates Mittel um sich des Rahmens zu entledigen. Ein Tool für derlei Zwecke ist mir bisher nicht bekannt, sollte jedoch auch kein Problem darstellen.

IlCoq · **Registriert:** 21.05.07, 16:24

Eine Möglichkeit wäre, das Fenster so zu vergrößern und zu verschieben, dass Ramen und Titelleiste unsichtbar sind, zum Beispiel mit einem Autohotkey-Skript.
Oder vielleicht ein WIndows-Theme ohne Titelleiste.

Alex.HH · **Registriert:** 04.02.04, 0:07

Evtl HSI,
http://www.hawkeyetech.com/products/freeware.htm
frag mich nicht , wie ;-)

JFierce7 · **Registriert:** 09.12.04, 16:40

Das geht mit AutoHotkey:

Code:

WinSet, Style, -0xC00000, A

entfernt die Titelleiste des aktiven Fensters. Ausgelöst durch Hotkey - fertig.

SanskritFritz · **Verfasst:** 27.07.07, 10:48

Heh, das gefällt mir. Bleibt noch die frage, wir setze ich es zurück:

Code:

WinSet, Style, +0xC00000, A

tobi-lu · **Registriert:** 19.06.05, 14:41

Insgesamt also z.B. so:

Code:

#F12::
WinGet, tb, Style, A
if (tb & 0xC00000)
{
   WinSet, Style, -0xC00000, A
   WinMaximize, A
}
else
{
   WinSet, Style, +0xC00000, A
   WinRestore, A
}
return

Damit kann man mit Win+F12 umschalten.

@thehop hat geschrieben:

Die Menüs der Toolbar, Taskleisten sollten dabei als Einblendmenüs erhalten bleiben
(z.B. bei Mausberührung der Bildschirmränder oder/und Kontextmenü, Systrayoption etc.)

Wüsste nicht wie was in der Art mit AHK hinkriegen könnte...

Icfu · **Registriert:** 28.05.05, 3:29 **Wohnort:** Rheinland

2007/12/14 Version 1.2
+ Shortcut Shift+F11: gleiche Funktionalität ohne Maximierung

2007/07/27 Version 1.1
+ Auch die Menüleiste wird entfernt.
+ Der Menü- und Maximierungsstatus aller Fenster wird in einer temporären Datei (Scriptname.ahk.tmp im Arbeitsverzeichnis) gesichert und wiederhergestellt.
* Shortcut Strg+F11: keine Kollision mit programmeigener Vollansicht-Funktion

Kompilierte Exe+Source:
http://icfu.totalcmd.net/Scripts/AHK_ToggleWindow.zip

ToggleWindow.ahk:

Code:

GroupAdd, Excludes, Windows Task-Manager ahk_class #32770
GroupAdd, Excludes, ahk_class _As12__TaskSwitchXP_TaskSwitchWnd_
GroupAdd, Excludes, ahk_class Progman
GroupAdd, Excludes, ahk_class Shell_TrayWnd

#IfWinNotActive, ahk_group Excludes

^F11::
Critical
b_MaximizeWindow := true
ToggleWindow(b_MaximizeWindow)
Return

+F11::
Critical
b_MaximizeWindow := false
ToggleWindow(b_MaximizeWindow)
Return

ToggleWindow(ByRef b_MaximizeWindow)
{
  h_Window := WinActive("A")
  IniFile := A_ScriptName . ".tmp"
  IniRead, v_Array, %IniFile%, Handles, %h_Window%, 0
  If !(v_Array)
    {
      h_Menu := DllCall("GetMenu", "UInt", h_Window)
      WinGet, b_WindowMaximized, MinMax
      DllCall("SetMenu", "UInt", h_Window, "UInt", 0)
      If (b_MaximizeWindow)
        WinMaximize
      WinSet, Style, -0xC00000
      IniWrite, %h_Menu%`,%b_WindowMaximized%, %IniFile%, Handles, %h_Window%
    }
  Else
    {
      StringSplit, v_Array, v_Array, `,
      h_Menu := v_Array1
      b_WindowMaximized := v_Array2
      DllCall("SetMenu", "UInt", h_Window, "UInt", h_Menu)
      If !(b_WindowMaximized AND b_MaximizeWindow)
        WinRestore
      WinSet, Style, +0xC00000
      IniDelete, %IniFile%, Handles, %h_Window%
    }
}

#IfWinNotActive

Icfu

@thehop · **Registriert:** 15.07.05, 1:33 **Wohnort:** europa.at

Hallo Icfu

Soeben ausprobiert - läuft prima! - verwende ich jetzt bei Opera statt F11
weil mit deinem Tool die Opera Menüleisten erhalten bleiben - danke für die Tüftelei!

servus @thehop

PS:
Genial wär noch eine Option um nur den aktiven Fensterinhalt anzuzeigen,
also ähnlich wie Screenshotprogramme nur diese "capturen" können?

hubutz · **Registriert:** 20.12.06, 9:06

Hallo,

das Skript ist ja toll. Wäre es noch möglihc eine 2. tastenbelegung für dieselbe Funktion nur ohne das Maximieren einzufügen?
Habe einfach den ganzen Code kopiert und das "WinMaximize" auskommentiert, und nen neuen Key belegt, aber... dAs mag es nicht *ggg*

Danke

Icfu · **Registriert:** 28.05.05, 3:29 **Wohnort:** Rheinland

Hab's eingebaut...

Icfu

hubutz · **Registriert:** 20.12.06, 9:06

Merci!

hubutz · **Registriert:** 20.12.06, 9:06

Icfu:
Das Script scheint nicht bei VirtualBox zu funktionieren (schade eigentlich, habe mir nen kleinen Server aufgesetzt, die Schaltfläche in der Taskbar hab ich schon mit nem anderen Skript von dir ausgeblendet, die Ränder gehen aber wohl nicht weg).

Hast du das zufällig auch laufen? Wäre klasse

Gibts eigentlich irgendwo ne gesammelte Icfu AHK-Skritpsammlung? *ggg*

Liebe Grüße,
hubutz

Icfu · **Registriert:** 28.05.05, 3:29 **Wohnort:** Rheinland

Das Skript kann nur Standardmenüs ausblenden, mehr ist nicht drin.

Auf dem EFB gibt's einen Skript-Sammelthread für AHK und AutoIt-Skripte. 'ne Sammelstelle nur mit meinen ist mir nicht bekannt.

Icfu

hubutz · **Registriert:** 20.12.06, 9:06

Schade eigentlich. Die Sammlung hab ich wohl bisher immer übersehen. Danke für den Hinweis darauf!

EFB.nu

AHK_ToggleWindow 1.2 >> Programmfenster ohne Titelleiste und Rahmen anzeigen

Informationen